home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / R-Shows / (c)woc iii 85.d64 / disk tidier.z (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  2KB  |  69 lines
  1. 10 REM DISK TIDIER, DAVID WILLIAMS, 1983
  2. 20 REM MODIFIED BY  DAVID BRADLEY,  1983
  3. 30 :
  4. 40 REM PROGRAM HELPS WITH THE CHORE OF
  5. 50 REM DELETING UNWANTED FILES FROM DISKS.
  6. 60 REM PROGRAM IS IN BASIC 2.0... SHOULD
  7. 70 REM WORK ON PET/CBM'S OR ON COMMODORE-64
  8. 80 :
  9. 90 N=0:DIM F$(500)
  10. 100 PRINT:PRINT"WHICH DRIVE? (0/1) ";
  11. 110 GET DN$:IF DN$ <"0" OR DN$ > "1" THEN 110
  12. 120 PRINT DN$:PRINT
  13. 130 OPEN15,8,15
  14. 140 OPEN1,8,0,"$"+DN$
  15. 150 INPUT#15,E,E$:IF E$<>"OK" THEN PRINT E$:GOTO 680
  16. 160 GET#1,G$,G$,G$,G$:IFG$=""THEN680
  17. 170 GET#1,A$,B$:PRINT (ASC(A$+CHR$(0))+256*ASC(B$+CHR$(0)));
  18. 180 GET#1,G$:IFG$="" THEN 200
  19. 190 PRINT G$;:GOTO 180
  20. 200 PRINT: PRINT:PRINT "S[146]CRATCH OR L[146]EAVE FOLLOWING FILES?"
  21. 210 PRINT:GET#1,G$,G$:IFG$=""THEN380
  22. 220 GET#1,G$,G$
  23. 230 F$=""
  24. 240 GET#1,G$:IFG$="" THEN 210
  25. 250 IF G$<>CHR$(34)THEN240
  26. 260 GET#1,G$:IFG$=CHR$(34)THEN280
  27. 270 F$=F$+G$:GOTO260
  28. 280 DB$="                "
  29. 290 LF=LEN(F$):FF$=F$+LEFT$(DB$,16-LF)
  30. 300 PRINTFF$," ";
  31. 310 GET G$:IF G$<>"S" AND G$<>"L" THEN 310
  32. 320 IFG$="S"THENGG$="SCRATCH"
  33. 330 IFG$="L"THENGG$="LEAVE"
  34. 340 PRINT"   ";GG$;"[146]";
  35. 350 IF G$="S" THEN F$(N)=F$:N=N+1
  36. 360 GET#1,G$:IF G$<>"" THEN 360
  37. 370 GOTO210
  38. 380 N=N-1:CLOSE1
  39. 390 IF N<0 THEN 680
  40. 400 PRINT:PRINT "LIST OF FILES TO BE SCRATCHED:":PRINT
  41. 410 FOR I=0 TO N
  42. 420 PRINT F$(I)
  43. 430 FOR J=1 TO 500:NEXT
  44. 440 NEXT
  45. 450 PRINT:PRINT "CORRECT? (Y/N) ";
  46. 460 GET G$:IF G$<>"Y" AND G$<>"N" THEN 460
  47. 470 PRINTG$
  48. 480 IF G$="Y" THEN 540
  49. 490 PRINT:PRINT "A[146]BORT OR D[146]ISPLAY LIST AGAIN? ";
  50. 500 GET G$:IF G$<>"A" AND G$<>"D" THEN 500
  51. 510 PRINT G$
  52. 520 IF G$="A" THEN 680
  53. 530 GOTO 400
  54. 540 PRINT:PRINT "WORKING.... COME BACK LATER!":PRINT
  55. 550 PRINT#15,"V";DN$
  56. 560 PRINT"COLLECTING FOR FIRST TIME"
  57. 570 INPUT#15,E,E$:IFE$<>"OK" THEN PRINTE$:GOTO 680
  58. 580 FOR I=0 TO N
  59. 590 PRINT#15,"S";DN$;":";F$(I)
  60. 600 PRINT "SCRATCHING ";F$(I)
  61. 610 INPUT#15,E,E$,E1
  62. 620 IF E$<>"FILES SCRATCHED" OR E1<>1 THEN PRINT E;E$;E1:GOTO680
  63. 630 NEXT
  64. 640 PRINT#15,"V";DN$
  65. 650 PRINT"COLLECTING FOR SECOND TIME"
  66. 660 INPUT#15,E,E$:IFE$<>"OK" THEN PRINTE$:GOTO 680
  67. 670 PRINT:PRINT"ALL DONE"
  68. 680 CLOSE1:CLOSE15:END
  69.